group = "com.esotericsoftware.spine"
version = "4.2.0"

ext {
    libgdxVersion = "1.12.1"
    javaVersion = 8
}

allprojects {
    apply plugin: "java"

    sourceSets.main.java.srcDirs = ["src"]

    repositories {
        mavenLocal()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
        mavenCentral()
    }
}

project("spine-libgdx") {
    apply plugin: "java-library"

    dependencies {
        implementation "com.badlogicgames.gdx:gdx:$libgdxVersion"
    }
}

project("spine-skeletonviewer") {
    jar {
        duplicatesStrategy = DuplicatesStrategy.INCLUDE

        manifest {
            attributes "Main-Class": "com.esotericsoftware.spine.SkeletonViewer"
        }

        from {
            configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
        }
    }
}

configure(subprojects - project("spine-libgdx")) {
    sourceSets.main.resources.srcDirs = ["assets"]

    dependencies {
        implementation project(":spine-libgdx")
        implementation "com.badlogicgames.gdx:gdx:$libgdxVersion"
        implementation "com.badlogicgames.gdx:gdx-platform:$libgdxVersion:natives-desktop"
        implementation "com.badlogicgames.gdx:gdx-backend-lwjgl3:$libgdxVersion"
        implementation "com.badlogicgames.gdx:gdx-lwjgl3-glfw-awt-macos:$libgdxVersion"
        implementation "com.badlogicgames.gdx:gdx-box2d:$libgdxVersion"
        implementation "com.badlogicgames.gdx:gdx-box2d-platform:$libgdxVersion:natives-desktop"
    }
}